fps_project_1/scripts/gun.gd

extends Node3D


@export_group("Gun Feel")
@export var gun_name : String
@export var gun_icon : Texture2D
@export_enum("Light", "Medium", "Heavy", "Shotgun", "Rocket") var ammo_type: int
@export_enum("Auto", "Single", "Burst") var fire_mode: int
@export var gun_info : gun_stats
@export var hitscan_enabled : bool = false
@export var fov_zoom_amt = .98
@export var ads : bool = false
@export var recoil_amount : Vector3 = Vector3(.2,.05,.05)
@export var kick_amount : float = .1
@export var max_ammo = 15
@export var start_mags = 3
@export var bullet_damage = 1
@export var smoke_enabled : bool = false
@export var bullet_force_mod = 5.0
@export var bullet_speed = 150
@export var bullet_drop = .3
@export var random_spread_amt = 1.0
@export var fire_pitch_scale_amt = .2
@export_group("Gun Assets")
@export_subgroup("Main Assets")
@export var r_hand_location : Node
@export var l_hand_location : Node
@export var flare_light : Node
@export var bullet : Resource
@export var bullet_fake : Resource
@export var bullethole : Resource
@export var casing : Resource
@export var mag : Resource
@export_subgroup("Raycast Nodes")
@export var anim_player : Node
@export var barrel_raycast : Node
@export var casing_ejector : Node
@export var mag_ejector : Node
@export_subgroup("Audio Clips")
@export var audio_fire : Node
@export var audio_empty : Node
@export var audio_reload : Node

@onready var player = get_tree().current_scene.player
@onready var level_control = get_tree().current_scene
@onready var muzzle_smoke = preload("res://assets/muzzle_smoke.tscn")

var start_position
var start_rotation
var random_spread_start
var cycle_count_start
var cycle_count
var rng = RandomNumberGenerator.new()
var gun_index

# Called when the node enters the scene tree for the first time.
func _ready():
	random_spread_start = random_spread_amt
	
	if fire_mode == 0:
		cycle_count = 1
		cycle_count_start = 1
	elif fire_mode == 1:
		cycle_count = 1
		cycle_count_start = 1
	elif fire_mode == 2:
		cycle_count = 3
		cycle_count_start = 3
	


# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(_delta):
	pass


func reload_finished():
	if player.ammo_reserve[str(ammo_type)] >= max_ammo:
		player.gun_ammo[gun_name] += max_ammo
		player.ammo_reserve[str(ammo_type)]  -= max_ammo
	else:
		player.gun_ammo[gun_name] += player.ammo_reserve[str(ammo_type)]
		player.ammo_reserve[str(ammo_type)] -= player.ammo_reserve[str(ammo_type)]

func shoot(delta):
	print("GUN AMMO: ",player.gun_ammo)
	print("RESERVE AMMO: ",player.ammo_reserve)
	if player.gun_ammo[gun_name] > 0 and cycle_count > 0:
		if !anim_player.is_playing():
			player.gun_ammo[gun_name] -= 1
			#audio and anims
			audio_fire.pitch_scale = 1 + rng.randf_range(-fire_pitch_scale_amt,fire_pitch_scale_amt) 
			audio_fire.play()
			anim_player.play("shoot")
			vibration()
			bullet_fire()
			hitscan_fire()
			spawn_casing()
			if smoke_enabled:
				spawn_muzzle_smoke()
			player.recoil.add_recoil(Vector3(0,recoil_amount.y,recoil_amount.z),10,10)
			player.recoil.add_gun_recoil(recoil_amount.x)
			#player.velocity += player.bullet_ray.global_basis * Vector3(0,0, kick_amount)
			SignalBus.emit_signal("shot_fired")
			if fire_mode != 0:
				cycle_count -= 1

	elif !anim_player.is_playing() and cycle_count != 0:
		anim_player.play("empty")
		audio_empty.play()

func reload():
	if player.gun_ammo[gun_name]  < max_ammo and player.gun.anim_player.get_current_animation() != "reload" and player.ammo_reserve[str(ammo_type)] > 0:
		#player.reloading = true
		anim_player.play("reload")
		audio_reload.play()
		if anim_player.is_playing() and anim_player.current_animation == "reload":
			if player.gun_ammo[gun_name] == 0:
				player.gun_ammo[gun_name] = 0
			else:
				player.gun_ammo[gun_name] = 1

func spawn_mag():
	var instance_mag = mag.instantiate()
	instance_mag.position = mag_ejector.global_position
	instance_mag.transform.basis = mag_ejector.global_transform.basis
	instance_mag.linear_velocity += transform.basis * Vector3(0, -20, 0) + player.velocity
	get_tree().get_root().add_child(instance_mag)

func spawn_casing():
	# Casing transform
	var instance_casing = casing.instantiate()
	instance_casing.position = casing_ejector.global_position
	instance_casing.transform.basis = casing_ejector.global_transform.basis
	instance_casing.player_velocity = player.velocity * transform.basis
	get_tree().get_root().add_child(instance_casing)

func spawn_muzzle_smoke():
	var instance_smoke = muzzle_smoke.instantiate()
	instance_smoke.global_transform.basis = barrel_raycast.global_transform.basis
	
	add_child(instance_smoke)

func bullet_fire():
	var instance_bullet 
	if hitscan_enabled:
		instance_bullet = bullet_fake.instantiate()
	else:
		instance_bullet = bullet.instantiate()
	instance_bullet.position = player.bullet_ray.global_position
	#shoot bullet from real gun if gun is folded up
	if player.gun_folded == false:
		instance_bullet.transform.basis = player.bullet_ray.global_transform.basis
	else:
		instance_bullet.transform.basis = barrel_raycast.global_transform.basis
	instance_bullet.bullet_speed = bullet_speed
	instance_bullet.player_velocity = player.velocity * transform.basis
	instance_bullet.bullet_drop = bullet_drop
	instance_bullet.random_spread_amt = random_spread_amt
	instance_bullet.bullet_damage = bullet_damage
	instance_bullet.bullet_force_mod = bullet_force_mod
	instance_bullet.instance_bullethole = bullethole.instantiate()
	instance_bullet.player_position = player.global_position
	get_tree().current_scene.add_child(instance_bullet)

func hitscan_fire():
	if hitscan_enabled:
		# Fire hitscan
		if player.gun_folded == false:
			player.bullet_ray.hitscan_fire(bullet_damage,bullet_force_mod,bullethole)
		else:
			barrel_raycast.hitscan_fire(bullet_damage,bullet_force_mod,bullethole)

func swapped_out():
	queue_free()

func vibration():
	Input.start_joy_vibration(0,.1,.5,.1)