extends Node3D

var start_position
var start_rotation
var random_spread_start
var cycle_count_start
var cycle_count

@export_group("Gun Feel")
@export_enum("Auto", "Single", "Burst") var fire_mode: int
@export var recoil_amount = .2
@export var max_ammo = 15
@export var start_mags = 3
@export var bullet_damage = 1
@export var kick_amount = 1
@export var bullet_speed = 150
@export var bullet_drop = .3
@export var random_spread_amt = 1.0
@export var fire_pitch_scale_amt = .2
@export_group("Gun Assets")
@export_subgroup("Main Assets")
@export var flare_light : Node
@export var bullet : Resource
@export var bullethole : Resource
@export var casing : Resource
@export var mag : Resource
@export_subgroup("Raycast Nodes")
@export var anim_player : Node
@export var barrel_raycast : Node
@export var casing_ejector : Node
@export var mag_ejector : Node
@export_subgroup("Audio Clips")
@export var audio_fire : Node
@export var audio_empty : Node
@export var audio_reload : Node

@onready var player = $"../../../../"
var rng = RandomNumberGenerator.new()

# Called when the node enters the scene tree for the first time.
func _ready():
	start_position = self.position
	start_rotation = self.rotation
	random_spread_start = random_spread_amt

	if fire_mode == 0:
		cycle_count = 1
		cycle_count_start = 1
	elif fire_mode == 1:
		cycle_count = 1
		cycle_count_start = 1
	elif fire_mode == 2:
		cycle_count = 3
		cycle_count_start = 3
	


# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta):
	pass


func _on_gun_anims_animation_finished(anim_name):
	if anim_name == "reload":
		if player.ammo_reserve >= max_ammo:
			player.ammo += max_ammo
			player.ammo_reserve -= max_ammo
			player.reloading = false
		else:
			player.ammo += player.ammo_reserve
			player.ammo_reserve -= player.ammo_reserve
			player.reloading = false

func shoot(player,delta):

	if player.ammo > 0 and cycle_count > 0:
		if !anim_player.is_playing():
			player.ammo -= 1
			#RECOIL --- fix later to happen over a period of time
			player.camera.rotation.x = clamp(lerp(player.camera.rotation.x, player.camera.rotation.x + recoil_amount, delta * 10), deg_to_rad(-90), deg_to_rad(60))
			#(ADD PLAYER KICK HERE. RELATIVE TO GUN POSITION)
			audio_fire.pitch_scale = 1 + rng.randf_range(-fire_pitch_scale_amt,fire_pitch_scale_amt) 
			audio_fire.play()
			anim_player.play("shoot")
			
			# instance bullet
			var instance_bullet = bullet.instantiate()
			instance_bullet.position = player.bullet_ray.global_position
			#shoot bullet from real gun if gun is folded up
			if player.gun_folded == false:
				instance_bullet.transform.basis = player.bullet_ray.global_transform.basis
			else:
				instance_bullet.transform.basis = barrel_raycast.global_transform.basis	
			instance_bullet.bullet_speed = bullet_speed
			instance_bullet.bullet_drop = bullet_drop
			instance_bullet.random_spread_amt = random_spread_amt
			instance_bullet.gun = self
			get_tree().get_root().add_child(instance_bullet)
			
			# Casing transform
			var instance_casing = casing.instantiate()
			instance_casing.position = casing_ejector.global_position
			instance_casing.transform.basis = casing_ejector.global_transform.basis
			get_tree().get_root().add_child(instance_casing)
			
			if fire_mode == 1 or fire_mode == 2:
				cycle_count -= 1

	elif !anim_player.is_playing() and cycle_count != 0:
		anim_player.play("empty")
		audio_empty.play()

func reload(player,delta):
	if player.ammo < max_ammo and player.reloading == false and player.ammo_reserve > 0:
		player.reloading = true
		anim_player.play("reload")
		audio_reload.play()
		if anim_player.is_playing() and anim_player.current_animation == "reload":
			if player.ammo == 0:
				player.ammo = 0
			else:
				player.ammo = 1

func spawn_mag():
	var instance_mag = mag.instantiate()
	instance_mag.position = mag_ejector.global_position
	instance_mag.transform.basis = mag_ejector.global_transform.basis
	get_tree().get_root().add_child(instance_mag)